作者cutekid (可愛小孩子)
看板Office
標題Re: [算表] 提取單一儲存格中的數量加總
時間Thu Aug 17 11:30:40 2023
如圖:
https://i.imgur.com/Qt03iwJ.png
B1公式:
=LET(
Item,
SORT(UNIQUE(DROP(REDUCE(0,A2:A3,LAMBDA(x,y,HSTACK(x,TEXTSPLIT(y,
CHAR(ROW(48:57)),,1)))),,1),1),,,1),
REDUCE(
Item,
A2:A3,
LAMBDA(result,input,
VSTACK(result,IFNA(LET(x,TEXTSPLIT(input,CHAR(ROW(48:57)),,1),
INDEX(TEXTSPLIT(input,x,,1),MATCH(Item,x,))),""))
)
)
)
※ 引述《freePrester (Prester)》之銘言：
: 軟體: Excel
: 版本: 365
: 版友好，最近遇到幾個問題，想知道有沒有比較有效率的方法可以解決
: https://i.imgur.com/wAe3vxc.png
: 如上圖，A1 的格中代表 AAA 有 1 個、BB 有 2 個以此類推
: 要怎麼做才能快速將格中所有的數進行加總如 A2 = 1+2+13+5 = 21
: 我的資料有上百筆，但裡面的種類不盡相同 (如 A1、B1 那樣）
: 更進一步，我想將這些資料如下分類出來，有辦法做到嗎？
: https://i.imgur.com/cytYzR2.png
: 先謝過各位大神
--
※ 發信站: 批踢踢實業坊(ptt.cc), 來自: 136.226.241.82 (臺灣)
※ 文章網址: https://webptt.com/m.aspx?n=bbs/Office/M.1692243042.A.C8A.html
1F：→ freePrester: 感謝，那單純做總合有辦法辦到嗎？ 08/17 11:40
2F：→ freePrester: 像第一張圖那樣 08/17 11:40
3F：→ freePrester: 想說單純做總和的話應該不用動到這麼大的公式 08/17 11:43
B1公式(下拉): =SUM(1*TEXTSPLIT(A2,TEXTSPLIT(A2,CHAR(ROW($48:57)),,1),,1))
※ 編輯: cutekid (136.226.241.82 臺灣), 08/17/2023 11:46:19
4F：→ windknife18: =SUM(--TEXTSPLIT(A1,CHAR(SEQUENCE(26,,65)),,1)) 08/17 11:52
5F：→ freePrester: 謝謝各路大神，我再好好研究 08/17 12:30
6F：→ cutekid: 不客氣，祝順心！ 08/17 12:34
7F：→ freePrester: w大的方法是不是中間不是英文就不能用了？ 08/17 12:36
8F：→ windknife18: 對，只能用英文，如果有其他的文字，請用C大公式 08/17 13:10
9F：→ freePrester: 謝謝說明 08/17 13:53
10F：→ windknife18: 不客氣 :) 08/17 15:01