作者cutekid (可爱小孩子)
看板Office
标题Re: [算表] 提取单一储存格中的数量加总
时间Thu Aug 17 11:30:40 2023
如图:
https://i.imgur.com/Qt03iwJ.png
B1公式:
=LET(
Item,
SORT(UNIQUE(DROP(REDUCE(0,A2:A3,LAMBDA(x,y,HSTACK(x,TEXTSPLIT(y,
CHAR(ROW(48:57)),,1)))),,1),1),,,1),
REDUCE(
Item,
A2:A3,
LAMBDA(result,input,
VSTACK(result,IFNA(LET(x,TEXTSPLIT(input,CHAR(ROW(48:57)),,1),
INDEX(TEXTSPLIT(input,x,,1),MATCH(Item,x,))),""))
)
)
)
※ 引述《freePrester (Prester)》之铭言：
: 软体: Excel
: 版本: 365
: 版友好，最近遇到几个问题，想知道有没有比较有效率的方法可以解决
: https://i.imgur.com/wAe3vxc.png
: 如上图，A1 的格中代表 AAA 有 1 个、BB 有 2 个以此类推
: 要怎麽做才能快速将格中所有的数进行加总如 A2 = 1+2+13+5 = 21
: 我的资料有上百笔，但里面的种类不尽相同 (如 A1、B1 那样）
: 更进一步，我想将这些资料如下分类出来，有办法做到吗？
: https://i.imgur.com/cytYzR2.png
: 先谢过各位大神
--
※ 发信站: 批踢踢实业坊(ptt.cc), 来自: 136.226.241.82 (台湾)
※ 文章网址: https://webptt.com/cn.aspx?n=bbs/Office/M.1692243042.A.C8A.html
1F：→ freePrester: 感谢，那单纯做总合有办法办到吗？ 08/17 11:40
2F：→ freePrester: 像第一张图那样 08/17 11:40
3F：→ freePrester: 想说单纯做总和的话应该不用动到这麽大的公式 08/17 11:43
B1公式(下拉): =SUM(1*TEXTSPLIT(A2,TEXTSPLIT(A2,CHAR(ROW($48:57)),,1),,1))
※ 编辑: cutekid (136.226.241.82 台湾), 08/17/2023 11:46:19
4F：→ windknife18: =SUM(--TEXTSPLIT(A1,CHAR(SEQUENCE(26,,65)),,1)) 08/17 11:52
5F：→ freePrester: 谢谢各路大神，我再好好研究 08/17 12:30
6F：→ cutekid: 不客气，祝顺心！ 08/17 12:34
7F：→ freePrester: w大的方法是不是中间不是英文就不能用了？ 08/17 12:36
8F：→ windknife18: 对，只能用英文，如果有其他的文字，请用C大公式 08/17 13:10
9F：→ freePrester: 谢谢说明 08/17 13:53
10F：→ windknife18: 不客气 :) 08/17 15:01