作者jfsu (水精灵)
看板Electronics
标题Re: [问题] hspice模拟inverter求Vih Vil
时间Mon Mar 21 16:44:07 2011
※ 引述《Dusuren ()》之铭言:
: 小弟最近开始接触hspice软体 在模拟inverter中
: 不知道是不是有指令可以直接求出 Vih Vil
: 还是只能一点一点慢慢找出斜率等於-1那点 冏
: 谢谢
* VIL, VIH, VOL, VOH, NMH, NML measurement
.global gnd vdd
.option post brief runlvl=5
.option nomod acct post=1 nopage
.option scale=1e-6
****Library model,simplified circuit and node initial file******
.prot
.lib './XXXX.l(自己的lib档)' TT
.unprot
************************************
vvdd vdd 0 vcc
vgnd gnd 0 0
.param vcc=3.0v
.temp 25
************************************
.subckt inv Y A lp=0.35 wp=0.3 ln=0.3 wn=0.3
MN0 Y A gnd gnd NL w=wn l=ln
MP0 vdd A Y vdd PL w=wp l=lp
.ends inv
x1 2 1 inv wp=2.12 wn=0.82
x2 4 3 inv wp=2.12 wn=0.82
vx 3 1 0.01
vin 1 0 dc 0
*********************************************************************
.DC vin 0 3 0.01
***********************************************************************^
***********底下是求斜率等於负一(依书上Vil与Vih定义)
.measure dc voh find v(2) at 0
.measure dc vol find v(2) at 3
.measure dc vil find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=1
.measure dc vih find v(1) when par '(v(4)-v(2))/0.01'=-1 cross=2
.measure dc NMH param='voh-vih'
.measure dc NML param='vil-vol'
*****底下是另一种求法,直接用hspcie里的微分参数DERIV()~
.MEASURE DC VIL1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VIH1 FIND V(1) WHEN DERIV('V(2)')=-1 cross=2
.MEASURE DC VOHU FIND V(2) WHEN DERIV('V(2)')=-1 cross=1
.MEASURE DC VOLU FIND V(2) WHEN DERIV('V(2)')=-1 cross=2
.measure dc NML1 param='VIL1-VOLU'
.measure dc NMH1 param='VOHU-VIH'
.end
底下附上两种sim出来的结果,好像略有差异。
个人觉得第二种的NML与NMH比较符合书上的定义。
都给你参考,因为要考虑NMOS是是depltion or enhancement load
.TITLE '* vil, vih, vol, voh, nmh, nml measurement'
voh=3.0
vol=0
vil=1.1226
vih=1.6526
nmh=1.3474
nml=1.1226
vohu=2.7774
volu=0.1932
vil1=1.1326
vih1=1.6626
nml1=0.9394
nmh1=1.1248
--
在台湾,何谓R&D工程师?
1.Reverse and Decap :IC反相工程,去胶,打开封装,拍照,复制电路布局。
2.Resign and Die :没死的就操到辞职,没辞职的就操到死。
3.Rework and Debug :计画永远跟不上变化,变化永远跟不上老板的一句话!
4.Relax and Delay :太过於轻松(Relax),那麽就会Random Death (随时阵亡)
但是外派到大陆的台湾郎,晚上是R (鸭)陪客户,白天是D (猪)任人宰割!
--
※ 发信站: 批踢踢实业坊(ptt.cc)
◆ From: 203.66.222.12
1F:推 Dusuren:感谢大大 03/21 22:05
2F:→ kbwei:MP0 vdd A Y vdd PL w=wp l=lp? MP0 Y A vdd vdd PL .... 03/21 22:45
3F:推 kk123:Low-V 的 PMOS D,S 可互换,所以原本的写法也可以。 03/22 00:27