作者UndeadSion (UndeadSion)
看板EzHotKey
標題Re: [請問] 怎麼送出input1的文字-autoit
時間Sat Jun 27 14:17:06 2009
※ 引述《ledup (我是男子漢)》之銘言：
: 我想要按f8 然後 會在記事本 自動輸出 我打在
: $input1裡面的文字，不過怎麼只有 打出3 而以
: 而且我裡面也沒有打3啊，超奇怪
: 程式碼要怎麼改，麻煩高手幫幫我
以下參考看看，如果是要逐字送出的話，請按 F9
---------------->8---------------->8---------------- 請沿此線剪下 ----
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
HotKeySet("{F8}","keyit") ; F8 一次貼上
HotKeySet("{F9}","keyit2") ; F9 逐字送出
$Form1 = GUICreate("GUI 設計編輯區", 620, 407, -1, -1)
$Edit1 = GUICtrlCreateEdit("", 20, 10, 580, 380) ; 改用 Edit 比較方便
GuiSetState()
While 1
$Msg = GUIGetMsg()
Switch $Msg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd
Func keyit()
If Not WinExists("[TITLE:未命名 - 記事本; CLASS:Notepad]") Then Return
$Text = GUICtrlRead($Edit1)
ControlCommand("[LAST]", "", "Edit1", "EditPaste", $Text)
EndFunc
Func keyit2()
If Not WinExists("[TITLE:未命名 - 記事本; CLASS:Notepad]") Then Return
$hNotepad = ControlGetHandle("[LAST]", "", "Edit1")
$Text = StringSplit(StringReplace(GUICtrlRead($Edit1), @CR, ""), "")
For $i = 1 To $Text[0]
DllCall("user32.dll", "int", "PostMessageW", "hwnd", $hNotepad, _
"uint", 0x286, "wparam", AscW($Text[$i]), "lparam", 0)
Sleep(100)
Next
EndFunc
---------------->8---------------->8---------------- 請沿此線剪下 ----
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 60.248.159.124
1F：推 ledup:感謝 06/27 15:18