作者rexx ()
站內EzHotKey
標題[AHK-] 視窗控制
時間Sun Jul 20 13:10:17 2008
這是我常用的一些控制視窗的小功能
win+v 將視窗置中
win+ctrl+v 調整大小為800x600並將視窗置中
win+方向鍵 移動視窗位置
win+1/2/3 切換視窗透明度並且置頂
win+4 切換置頂
--8<------
;center active window
#V::
WinGetPos, , , WinWidth, WinHeight, A
WinMove, A, , (A_ScreenWidth/2)-(WinWidth/2), (A_ScreenHeight/2)-(WinHeight/2)
return
#^V:: ;800x600
WinMove, A, , (A_ScreenWidth/2)-(800/2), (A_ScreenHeight/2)-(600/2), 800, 600
return
;move active window
#Left::MoveWindow(-1, 0)
#Right::MoveWindow(1, 0)
#Up::MoveWindow(0, -1)
#Down::MoveWindow(0, 1)
MoveWindow(dx, dy){
WinGetPos, WinPosX, WinPosY, , , A
WinMove, A, , WinPosX+dx, WinPosY+dy
return
}
;toggle alwaysontop & transparency
#1::SetTransparency(64)
#2::SetTransparency(128)
#3::SetTransparency(192)
#4::WinSet, AlwaysOnTop, toggle, A
SetTransparency(trans){
WinGet, Transparency, Transparent, A
If Transparency
WinSet, Transparent, Off, A
else
WinSet, Transparent, %trans%, A
WinSet, AlwaysOnTop, toggle, A
return
}
--8<------
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 61.228.92.221
1F：推 emethxyz:這個很好用呢，怎麼沒人推XD 07/21 18:46
2F：推 alicelee1218:隔好久推 好用 10/17 10:47