作者pericles (吼~)
看板EZsoft
標題Re: [請問] 合併與排除txt
時間Tue Jul 7 17:59:52 2020
@echo off
if "%1"=="" (
echo 至少要兩個檔案傳入
pause
goto :eof
)
if "%2"=="" (
echo 至少要兩個檔案傳入
pause
goto :eof
)
echo 合併完成檔名： merged.txt
echo 排除完成檔名： excluded.txt
copy %1 _merged.txt > nul
copy %1 merged.txt > nul
echo ==== 合併作業 ====
for %%a in (%*) do (
echo 合併中： %%a
findstr /lvxig:_merged.txt %%a >>merged.txt
copy merged.txt _merged.txt > nul
echo 已合併： %%a
)
del _merged.txt
echo [合併結果]：
type merged.txt
echo ==== 排除作業 ====
echo 排除中： %1 排除 %2 結果
findstr /lvxig:%2 %1 >excluded.txt
echo %1 已排除 %2 中內容
echo [排除結果]：
type excluded.txt
pause
========================= 我是分隔線 ===============================
分隔線以上內容所有文字複製存成 xxxxx.bat 檔
把要合併或要排除的檔選起來拖到 bat 檔上即可
合併支援多檔，結果檔名：merged.txt
檔案1+檔案2+檔案3...檔案n
排除支援兩檔 結果檔名：excluded.txt
點著檔案1拖兩檔上去即為1排除2
點著檔案2拖兩檔上去即為2排除1
拼拼湊湊出來的，應該還有最佳化空間
※ 引述《sillycat79 (糊塗喵咪)》之銘言：
: 很久以前有一個整理資料的小工具，但現在找不到
: 他可以合併多個txt檔案，也可以排除某個檔案中有的資料
: 例如：
: a.txt 內容
: 1
: 2
: 3
: b.txt 內容
: 2
: 3
: 4
: 功能一：合併a,b，輸出
: 1
: 2
: 3
: 4
: 功能二：a排除b，輸出
: 1
: 不知道有沒有類似能做這兩件事情的小軟體，謝謝
--
※ 發信站: 批踢踢實業坊(ptt.cc), 來自: 60.251.71.34 (臺灣)
※ 文章網址: https://webptt.com/m.aspx?n=bbs/EZsoft/M.1594115994.A.1EC.html
1F：推 shala: 不錯，但CMD遇到Unicode應該就沒法了 07/07 18:17
2F：→ sillycat79: 謝謝分享～～ 07/09 15:35
3F：推 storyofwind: CHCP 65001可以處理這邊的unicode嗎 07/09 15:43