作者friven2002 (friven)
看板Cad_Cae
標題[請益] ANSYS銲接分析
時間Wed Apr 30 19:42:19 2008
下面是從書本上找到的一個銲接例，完整可跑完
但有個地方我看不懂。
TABLE中的數值依照定義應是熱流率，但為何沒有規則性。
也看不出是什麼，請高手幫忙看一下那是哪種形式來加載～謝謝。
/FILNAME,EX5-4,1 !設定工作名
/TITLE,The Thermal Analysis of the Welding !設定工作標題
/PREP7 !進入前處理模塊
!******************************
!定義參數
!******************************
LENGTH1=0.004 !定義參數變量
LENGTH2=0.008
LENGTH3=0.03
WIDTH1=0.02
WIDTH2=0.04
HEIGHT=0.003
DIA=0.001
ah=DIA/2
chf=2*ah
chb=8*ah
bh=0.005
rf=2*chf/(chf+chb)
rb=2*chb/(chf+chb)
W=500
STEP=0.002
COUNT=WIDTH1/STEP
V=0.004
!******************************
!定義單元類型
!******************************
ET,1,SOLID70
!******************************
!定義材料參數
!******************************
!定義導熱係數1
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,100
MPTEMP,3,200
MPTEMP,4,300
MPTEMP,5,400
MPTEMP,6,500
MPTEMP,7,600
MPTEMP,8,700
MPTEMP,9,800
MPTEMP,10,900
MPTEMP,11,1000
MPTEMP,12,1100
MPTEMP,13,1200
MPTEMP,14,1500
MPTEMP,15,1700
MPTEMP,16,2500
MPDATA,KXX,1,,50.7 !定義對應溫度下的導熱係數數值
MPDATA,KXX,1,,48.2
MPDATA,KXX,1,,46.5
MPDATA,KXX,1,,41.5
MPDATA,KXX,1,,38.1
MPDATA,KXX,1,,34.2
MPDATA,KXX,1,,30.0
MPDATA,KXX,1,,31.8
MPDATA,KXX,1,,26.0
MPDATA,KXX,1,,26.8
MPDATA,KXX,1,,26.8
MPDATA,KXX,1,,28.8
MPDATA,KXX,1,,29.2
MPDATA,KXX,1,,35.0
MPDATA,KXX,1,,14.0
MPDATA,KXX,1,,14.2
!定義比熱容1
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,100
MPTEMP,3,200
MPTEMP,4,300
MPTEMP,5,400
MPTEMP,6,500
MPTEMP,7,600
MPTEMP,8,700
MPTEMP,9,800
MPTEMP,10,900
MPTEMP,11,1000
MPTEMP,12,1500
MPTEMP,13,1700
MPTEMP,14,2500
MPDATA,C,1,,470 ! 定義對應溫度下的比熱數值
MPDATA,C,1,,490
MPDATA,C,1,,515
MPDATA,C,1,,550
MPDATA,C,1,,590
MPDATA,C,1,,645
MPDATA,C,1,,725
MPDATA,C,1,,860
MPDATA,C,1,,835
MPDATA,C,1,,680
MPDATA,C,1,,650
MPDATA,C,1,,660
MPDATA,C,1,,780
MPDATA,C,1,,820
!定義密度
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,0 !定義表格的溫度數值
MPDATA,DENS,1,,7850 !定義對應溫度下的密度數值
!定義對流換熱係數
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,250
MPTEMP,3,400
MPTEMP,4,500
MPTEMP,5,750
MPTEMP,6,800
MPTEMP,7,1000
MPTEMP,8,1200
MPTEMP,9,1500
MPTEMP,10,1700
MPTEMP,11,2500
MPDATA,HF,1,,100 !定義對應溫度下的對流換熱係數數值
MPDATA,HF,1,,350
MPDATA,HF,1,,480
MPDATA,HF,1,,520
MPDATA,HF,1,,1000
MPDATA,HF,1,,1050
MPDATA,HF,1,,1500
MPDATA,HF,1,,2000
MPDATA,HF,1,,3000
MPDATA,HF,1,,3100
MPDATA,HF,1,,3500
!定義材料號2的相關屬性
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,100
MPTEMP,3,200
MPTEMP,4,300
MPTEMP,5,400
MPTEMP,6,500
MPTEMP,7,600
MPTEMP,8,700
MPTEMP,9,800
MPTEMP,10,1000
MPTEMP,11,1200
MPTEMP,12,1500
MPTEMP,13,2500
MPDATA,KXX,2,,11.9 !定義對應溫度下的導熱係數數值
MPDATA,KXX,2,,12.5
MPDATA,KXX,2,,14.3
MPDATA,KXX,2,,16.2
MPDATA,KXX,2,,17.3
MPDATA,KXX,2,,34.2
MPDATA,KXX,2,,32.0
MPDATA,KXX,2,,31.8
MPDATA,KXX,2,,26.0
MPDATA,KXX,2,,26.8
MPDATA,KXX,2,,28.8
MPDATA,KXX,2,,35.0
MPDATA,KXX,2,,14.2
!
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,100
MPTEMP,3,200
MPTEMP,4,500
MPTEMP,5,700
MPTEMP,6,1000
MPTEMP,7,1100
MPTEMP,8,1500
MPTEMP,9,1700
MPTEMP,10,2500
MPDATA,C,2,,460 !定義對應溫度下的比熱數值
MPDATA,C,2,,490
MPDATA,C,2,,530
MPDATA,C,2,,570
MPDATA,C,2,,610
MPDATA,C,2,,645
MPDATA,C,2,,855
MPDATA,C,2,,670
MPDATA,C,2,,780
MPDATA,C,2,,820
!
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,0 !定義表格的溫度數值
MPDATA,DENS,2,,8350 !定義對應溫度的密度數值
!
MPTEMP,,,,,,,, !初始化隨溫度變化的材料參數表格
MPTEMP,1,20 !定義表格的溫度數值
MPTEMP,2,100
MPTEMP,3,200
MPTEMP,4,400
MPTEMP,5,500
MPTEMP,6,1000
MPTEMP,7,1100
MPTEMP,8,1500
MPTEMP,9,1700
MPTEMP,10,2500
MPDATA,HF,2,,120 !定義對應溫度下的對流換熱係數值
MPDATA,HF,2,,210
MPDATA,HF,2,,300
MPDATA,HF,2,,460
MPDATA,HF,2,,540
MPDATA,HF,2,,1200
MPDATA,HF,2,,1200
MPDATA,HF,2,,2800
MPDATA,HF,2,,3000
MPDATA,HF,2,,3100
!*
!******************************
!建立幾何模型
!******************************
WPSTYLE,,,,,,,,0 !設定工作平面風格
BLOCK,0,LENGTH1,0,WIDTH1,0,HEIGHT, !生成長方體焊材1
BLOCK,LENGTH1,LENGTH2,0,WIDTH2,0,HEIGHT, !生成長方體焊材2
BLOCK,LENGTH2,LENGTH3,0,WIDTH2,0,HEIGHT, !生成長方體焊材3
VGLUE,all !粘接所有的體
!******************************
!劃分網格，生成有限元模型
!******************************
MAT,1 !激活材料編號1
ESIZE,HEIGHT/8,0 !設定網格單元尺寸
VSWEEP,1 !對編號為1的體進行sweep網格劃分
MAT,2 !激活材料編號2
ESIZE,HEIGHT/2,0 !設定網格單元尺寸
VSWEEP,4 !對編號為4的體進行sweep網格劃分
MSHAPE,1,3D !設定單元形狀為四面體單元
MSHKEY,0 !設定為自由網格劃分方式
VMESH,5 !對編號為5的體進行網格劃分
FINISH !前處理模塊結束
!******************************
!循環加載、求解
!******************************
!施加載荷
*DO,I,0,COUNT !循環求解開始
DISY=I*STEP !定義參數disy
T=(DISY+STEP)/V !定義參數t
/SOLU !進入求解模塊
ANTYPE,4 !設定分析類型
TRNOPT,FULL !設定為完全瞬態分析
TUNIF,293, !施加均勻初始溫度
OUTRES,BASIC,LAST !輸出最後一個子步的基本數據
TIME,T !設定求解結束時間
NROPT,FULL,,ON !設定Newton-Raphson選項
AUTOTS,1 !打開自動時間步
NSUBST,5,,,1 !設定子步數5
KBC,1 !階躍加載方式
LNSRCH,1 !打開線性搜索
TSRES,ERASE !清除時間步選項
TIMINT,1,THERM !設定時間積分
!*******************************
!焊接過程開始
!*******************************
NSEL,S,EXT !選擇外部節點
NSEL,U,LOC,X,0 !不選x=0的節點
SF,ALL,CONV,200,293 !在節點上施加對流換熱係數
ALLSEL,ALL !選擇全部圖元
!*******************************
!*******************************
!雙橢球熱源的加載
!*******************************
!*******************************
!前半球節點的選取
!*******************************
LOCAL,11,2,0,DISY,0, , , ,3,8, !生成局部坐標系11
NSEL,S,LOC,X,,DIA !選擇x=0~dia的節點
NSEL,R,LOC,Y,,90 !在當前選擇集中再選出y=0~90的節點
NSEL,R,LOC,Z,,90 !在當前選擇集中再選出z=0～90的節點
CM,NODEF,NODE !生成節點組件nodef
!*******************************
!前半球函數、表格定義
!*******************************
LOCAL,12,0,0,DISY,0, , , ,1,1, !生成局部坐標系12
!刪除以下參數變量
*DEL,TABLENAME
*DEL,TABLEMTID
*DEL,TABLE_ROW1
*DEL,TABLE_ROW2
*DEL,TABLE_ROW3
*DEL,TABLE_ROW4
*DEL,TABLE_ROW5
*DEL,TABLECSYS
*DEL,'TEMPF'
!定義表格各行
*SET,TABLENAME,'TEMPF'
*DIM,TABLE_ROW1,,1
*DIM,TABLE_ROW2,,1
*DIM,TABLE_ROW3,,1
*DIM,TABLE_ROW4,,1
*DIM,TABLE_ROW5,,1
!表格各行賦值
*SET,TABLE_ROW1(1),rf
*SET,TABLE_ROW2(1),w
*SET,TABLE_ROW3(1),chf
*SET,TABLE_ROW4(1),ah
*SET,TABLE_ROW5(1),bh
*SET,TABLECSYS,12
!表格各數據賦值
*DIM,%TABLENAME%,TABLE,7,38,1,,,,%TABLECSYS% !定義一個載荷表格
*SET,%TABLENAME%(0,0,1), 0.0,-999 !表格賦值
*SET,%TABLENAME%(2,0,1), 0.0
*SET,%TABLENAME%(3,0,1), %TABLE_ROW1(1)%
*SET,%TABLENAME%(4,0,1), %TABLE_ROW2(1)%
*SET,%TABLENAME%(5,0,1), %TABLE_ROW3(1)%
*SET,%TABLENAME%(6,0,1), %TABLE_ROW4(1)%
*SET,%TABLENAME%(7,0,1), %TABLE_ROW5(1)%
*SET,%TABLENAME%(0,1,1), 1.0, -1, 16, 3, 0, 0, 0
*SET,%TABLENAME%(0,2,1), 0.0, -2, 0, 6, 0, 0, -1
*SET,%TABLENAME%(0,3,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,4,1), 0.0, -1, 0, 1, -3, 3, 17
*SET,%TABLENAME%(0,5,1), 0.0, -2, 0, 1, -1, 3, 18
*SET,%TABLENAME%(0,6,1), 0.0, -1, 0, 0, 0, 0, 0
*SET,%TABLENAME%(0,7,1), 0.0, -3, 0, 1, 0, 0, -1
*SET,%TABLENAME%(0,8,1), 0.0, -4, 0, 1, -1, 2, -3
*SET,%TABLENAME%(0,9,1), 0.0, -1, 0, 2, 0, 0, 2
*SET,%TABLENAME%(0,10,1), 0.0, -3, 0, 1, 2, 17, -1
*SET,%TABLENAME%(0,11,1), 0.0, -1, 0, 2, 0, 0, 19
*SET,%TABLENAME%(0,12,1), 0.0, -5, 0, 1, 19, 17, -1
*SET,%TABLENAME%(0,13,1), 0.0, -1, 0, 1, -3, 4, -5
*SET,%TABLENAME%(0,14,1), 0.0, -3, 0, 2, 0, 0, 3
*SET,%TABLENAME%(0,15,1), 0.0, -5, 0, 1, 3, 17, -3
*SET,%TABLENAME%(0,16,1), 0.0, -3, 0, 2, 0, 0, 20
*SET,%TABLENAME%(0,17,1), 0.0, -6, 0, 1, 20, 17, -3
*SET,%TABLENAME%(0,18,1), 0.0, -3, 0, 1, -5, 4, -6
*SET,%TABLENAME%(0,19,1), 0.0, -5, 0, 1, -1, 1, -3
*SET,%TABLENAME%(0,20,1), 0.0, -1, 0, 2, 0, 0, 4
*SET,%TABLENAME%(0,21,1), 0.0, -3, 0, 1, 4, 17, -1
*SET,%TABLENAME%(0,22,1), 0.0, -1, 0, 2, 0, 0, 21
*SET,%TABLENAME%(0,23,1), 0.0, -6, 0, 1, 21, 17, -1
*SET,%TABLENAME%(0,24,1), 0.0, -1, 0, 1, -3, 4, -6
*SET,%TABLENAME%(0,25,1), 0.0, -3, 0, 1, -5, 1, -1
*SET,%TABLENAME%(0,26,1), 0.0, -1, 0, 3, 0, 0, -3
*SET,%TABLENAME%(0,27,1), 0.0, -5, 0, 1, -1, 3, -3
*SET,%TABLENAME%(0,28,1), 0.0, -1, 0, 1, -4, 3, -5
*SET,%TABLENAME%(0,29,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%TABLENAME%(0,30,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,31,1), 0.0, -1, 0, 1, 20, 3, 21
*SET,%TABLENAME%(0,32,1), 0.0, -2, 0, 1, -1, 3, 19
*SET,%TABLENAME%(0,33,1), 0.0, -1, 0, 3.14, 0, 0, -2
*SET,%TABLENAME%(0,34,1), 0.0, -4, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,35,1), 0.0, -1, 16, 3.14, 0, 0, 0
*SET,%TABLENAME%(0,36,1), 0.0, -2, 0, 1, -4, 3, -1
*SET,%TABLENAME%(0,37,1), 0.0, -1, 0, 1, -3, 4, -2
*SET,%TABLENAME%(0,38,1), 0.0, 99, 0, 1, -1, 0, 0
!施加表格熱源載荷
BF,NODEF,HGEN,%TEMPF% !在節點組件施加熱生成載荷
CMDELE,NODEF !刪除節點組件nodef
ALLSEL,ALL !選擇全部圖元
!*******************************
!後半球節點的選取
!*******************************
LOCAL,13,2,0,DISY,0, , , ,3,8, !生成局部坐標系13
NSEL,S,LOC,X,,DIA !選擇x=0~dia的節點
NSEL,R,LOC,Y,-90,0 !在當前選擇集中再選出y=-90~0的節點
NSEL,R,LOC,Z,,90 !在當前選擇集中再選出z=0～90的節點
CM,NODEB,NODE !生成節點組件nodeb
!*******************************
!後半球函數、表格定義
!*******************************
LOCAL,14,0,0,DISY,0, , , ,1,1, !生成局部坐標系14
!刪除以下參數變量
*DEL,TABLENAME
*DEL,TABLEMTID
*DEL,TABLE_ROW1
*DEL,TABLE_ROW2
*DEL,TABLE_ROW3
*DEL,TABLE_ROW4
*DEL,TABLE_ROW5
*DEL,TABLECSYS
*DEL,'TEMPB'
!定義表格各行
*SET,TABLENAME,'TEMPB'
*DIM,TABLE_ROW1,,1
*DIM,TABLE_ROW2,,1
*DIM,TABLE_ROW3,,1
*DIM,TABLE_ROW4,,1
*DIM,TABLE_ROW5,,1
!各行賦初值
*SET,TABLE_ROW1(1),rb
*SET,TABLE_ROW2(1),w
*SET,TABLE_ROW3(1),chb
*SET,TABLE_ROW4(1),ah
*SET,TABLE_ROW5(1),bh
*SET,TABLECSYS,14
!表格各數據賦值
*DIM,%TABLENAME%,TABLE,7,38,1,,,,%TABLECSYS% !定義一個表格載荷
*SET,%TABLENAME%(0,0,1), 0.0,-999 !表格賦值
*SET,%TABLENAME%(2,0,1), 0.0
*SET,%TABLENAME%(3,0,1), %TABLE_ROW1(1)%
*SET,%TABLENAME%(4,0,1), %TABLE_ROW2(1)%
*SET,%TABLENAME%(5,0,1), %TABLE_ROW3(1)%
*SET,%TABLENAME%(6,0,1), %TABLE_ROW4(1)%
*SET,%TABLENAME%(7,0,1), %TABLE_ROW5(1)%
*SET,%TABLENAME%(0,1,1), 1.0, -1, 16, 3, 0, 0, 0
*SET,%TABLENAME%(0,2,1), 0.0, -2, 0, 6, 0, 0, -1
*SET,%TABLENAME%(0,3,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,4,1), 0.0, -1, 0, 1, -3, 3, 17
*SET,%TABLENAME%(0,5,1), 0.0, -2, 0, 1, -1, 3, 18
*SET,%TABLENAME%(0,6,1), 0.0, -1, 0, 0, 0, 0, 0
*SET,%TABLENAME%(0,7,1), 0.0, -3, 0, 1, 0, 0, -1
*SET,%TABLENAME%(0,8,1), 0.0, -4, 0, 1, -1, 2, -3
*SET,%TABLENAME%(0,9,1), 0.0, -1, 0, 2, 0, 0, 2
*SET,%TABLENAME%(0,10,1), 0.0, -3, 0, 1, 2, 17, -1
*SET,%TABLENAME%(0,11,1), 0.0, -1, 0, 2, 0, 0, 19
*SET,%TABLENAME%(0,12,1), 0.0, -5, 0, 1, 19, 17, -1
*SET,%TABLENAME%(0,13,1), 0.0, -1, 0, 1, -3, 4, -5
*SET,%TABLENAME%(0,14,1), 0.0, -3, 0, 2, 0, 0, 3
*SET,%TABLENAME%(0,15,1), 0.0, -5, 0, 1, 3, 17, -3
*SET,%TABLENAME%(0,16,1), 0.0, -3, 0, 2, 0, 0, 20
*SET,%TABLENAME%(0,17,1), 0.0, -6, 0, 1, 20, 17, -3
*SET,%TABLENAME%(0,18,1), 0.0, -3, 0, 1, -5, 4, -6
*SET,%TABLENAME%(0,19,1), 0.0, -5, 0, 1, -1, 1, -3
*SET,%TABLENAME%(0,20,1), 0.0, -1, 0, 2, 0, 0, 4
*SET,%TABLENAME%(0,21,1), 0.0, -3, 0, 1, 4, 17, -1
*SET,%TABLENAME%(0,22,1), 0.0, -1, 0, 2, 0, 0, 21
*SET,%TABLENAME%(0,23,1), 0.0, -6, 0, 1, 21, 17, -1
*SET,%TABLENAME%(0,24,1), 0.0, -1, 0, 1, -3, 4, -6
*SET,%TABLENAME%(0,25,1), 0.0, -3, 0, 1, -5, 1, -1
*SET,%TABLENAME%(0,26,1), 0.0, -1, 0, 3, 0, 0, -3
*SET,%TABLENAME%(0,27,1), 0.0, -5, 0, 1, -1, 3, -3
*SET,%TABLENAME%(0,28,1), 0.0, -1, 0, 1, -4, 3, -5
*SET,%TABLENAME%(0,29,1), 0.0, -1, 7, 1, -1, 0, 0
*SET,%TABLENAME%(0,30,1), 0.0, -3, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,31,1), 0.0, -1, 0, 1, 20, 3, 21
*SET,%TABLENAME%(0,32,1), 0.0, -2, 0, 1, -1, 3, 19
*SET,%TABLENAME%(0,33,1), 0.0, -1, 0, 3.14, 0, 0, -2
*SET,%TABLENAME%(0,34,1), 0.0, -4, 0, 1, -2, 3, -1
*SET,%TABLENAME%(0,35,1), 0.0, -1, 16, 3.14, 0, 0, 0
*SET,%TABLENAME%(0,36,1), 0.0, -2, 0, 1, -4, 3, -1
*SET,%TABLENAME%(0,37,1), 0.0, -1, 0, 1, -3, 4, -2
*SET,%TABLENAME%(0,38,1), 0.0, 99, 0, 1, -1, 0, 0
!
BF,NODEB,HGEN,%TEMPB% !在節點組件nodeb上施加熱生成載荷
CMDELE,NODEB !刪除節點組件nodeb
ALLSEL,ALL !選擇全部圖元
SOLVE !開始求解
BFDELE,ALL,HGEN !刪除所有節點上的熱生成載荷
*ENDDO !循環求解結束
SAVE !保存數據庫
!***************************
!冷卻階段開始
!***************************
TIME,20 !設定求解結束時間
NSUBST,5,,,1 !設定子步數5
SOLVE !開始求解
/post26 !進入時間歷程後處理
nsol,2,1775,temp,, !將節點1775的溫度數據定義為變量2
nsol,3,1278,temp,, !將節點1278的溫度數據定義為變量3
nsol,4,1279,temp,, !將節點1279的溫度數據定義為變量4
nsol,5,1374,temp,, !將節點1374的溫度數據定義為變量5
nsol,6,1375,temp,, !將節點1375的溫度數據定義為變量6
nsol,7,2204,temp,, !將節點2204的溫度數據定義為變量7
plvar,2,3,4,5,6,7 !圖形顯示變量2~7的變化曲線
/post1 !進入通用後處理器
set,,,1,,5.5,,, !讀入時間5.5秒時的結果數據
plnsol,temp, !圖形顯示溫度分佈
finish !通用後處理模塊結束
/exit,all !退出並保存全部數據
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 140.118.105.177
1F：推 SoftballBoy:推薦你仿真在線論壇的熱分析討論區，很多焊接模擬 05/05 00:14