作者cjcat2266 (CJ Cat)
看板Flash
标题Re: [问题] 实作一个可监听的基本型别？
时间Thu May 13 21:53:30 2010
1F：→ cjcat2266:Proxy是可以做到此物件任何property被修改都丢事件 05/13 20:59
2F：→ cjcat2266:不然你就弄个Proxy当做一个data holder吧? 05/13 21:00
3F：→ cjcat2266:它拥有的property变更的时候都丢出式见这样 05/13 21:00
4F：→ etrexetrex:如果能动态的帮一个属性加丢出事件也是可以 05/13 21:14
使用Proxy监听property变更的方法如下
1. 继承Proxy class，需要有dynamic modifier
2. override setProperty(name:*, value:*)和getProperty(name:)
注意namespace是flash_proxy
3. implement IEventDispatcher
实作所有此interface标明的methods
已达到丢事件的目的
其实这个proxy就只是把一个Object包装起来
并且侧录存取此Object的property之所有行为而已
这是你的事件class
package {
import flash.events.Event;
public class PropertyChangeEvent extends Event{
public static const CHANGE:String = "propertyChange";
private var _name:*;
public function get name():* { return _name; }
private var _value:*;
public function get value():* { return _value; }
public function PropertyChangeEvent(
type:String,
name:*,
value:*) {
super(type, false, false);
_name = name;
_value = value;
}
}
}
}
这是你的Proxy class
最重要的method是setProperty(name:*, value:*)
其他的methods都很好理解
package {
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.IEventDispatcher;
import flash.utils.flash_proxy;
import flash.utils.Proxy;
public dynamic class DataProxy
extends Proxy
implements IEventDispatcher {
private var _dataHolder:Object = new Object();
private var _dispatcher:EventDispatcher =
new EventDispatcher();
public function addEventListener(
type:String,
listener:Function,
useCapture:Boolean = false,
priority:int = 0,
useWeakReference:Boolean = false):void {
_dispatcher.addEventListener(
type,
listener,
useCapture,
priority,
useWeakReference
);
}
public function removeEventListener(
type:String,
listener:Function,
useCapture:Boolean = false):void {
_dispatcher.removeEventListener(
type,
listener,
useCapture
);
}
public function dispatchEvent(event:Event):Boolean {
return _dispatcher.dispatchEvent(event);
}
public function hasEventListener(type:String):Boolean {
return _dispatcher.hasEventListener(type);
}
public function willTrigger(type:String):Boolean {
return _dispatcher.willTrigger(type);
}
override flash_proxy function getProperty(name:*):* {
return _dataHolder[name];
}
override flash_proxy function setProperty(
name:*,
value:*):void {
_dataHolder[name] = value;
dispatchEvent(
new PropertyChangeEvent(
PropertyChangeEvent.CHANGE,
name,
value
)
);
}
}
}
这是测试用的小程式
package {
import flash.display.Sprite;
import flash.events.Event;
public class Main extends Sprite {
public function Main():void {
var dataProxy:DataProxy = new DataProxy();
dataProxy.addEventListener(
PropertyChangeEvent.CHANGE,
onPropertyChange
);
dataProxy.x = 10;
dataProxy.y = 20;
/**
* OUTPUT
* --------------------------------
* property x has changed to: 10
* property y has changed to: 20
*/
}
private function onPropertyChange(
e:PropertyChangeEvent):void {
trace(
"property" + e.name +
"has changed to: " + e.value
);
}
}
}
--
CJ Cat = Croa'J Cat = Cockroach Cat = 西街凯特 = 蜚蠊猫 = 蟑螂猫
Blog
http://cjcat.blogspot.com
Gallery
http://cjcat2266.deviantart.com
ptt2 Board CJWorkshop - 阿多比闪光(Adobe Flash)研讨区
--
※ 发信站: 批踢踢实业坊(ptt.cc)
◆ From: 114.45.164.148
※ 编辑: cjcat2266 来自: 114.45.164.148 (05/13 21:55)
5F：推 etrexetrex:谢啦 05/13 22:09