作者UndeadSion (UndeadSion)
看板EzHotKey
标题Re: [AHK-] 请问如何终止正在执行一次的脚本
时间Sat Mar 21 05:12:02 2009
※ 引述《bohun ( )》之铭言：
: 这是倒数用的
: 现在我想要始执行时，再案启动键一次
: 让脚本终止
: 可是想不出来，我是超新手= =
: 请神人帮忙，谢谢
以下参考看看，按 F12 开始倒数或中止倒数
---------------->8---------------->8---------------- 请沿此线剪下 ----
; 设定执行命令，参数依序为：
; 1. 按键字串 2. 送出次数 3. 间隔时间 4. 延迟时间
CountCmd =
(c
{Asc 71}{Asc 79}, 1, 0, 1500 ; Send "GO"
{Numpad5}, 5, 0, 300
{Numpad4}, 5, 0, 300
{Numpad3}, 5, 0, 300
{Numpad2}, 5, 0, 300
{Numpad1}, 5, 0, 300
{Numpad0}, 6, 200, 600
)
CountDown := False
F12::
CountDown := !CountDown
If CountDown
SetTimer, CountStart, -1
Return
CountStart:
SetKeyDelay, 0
Loop, Parse, CountCmd, `n
{
StringSplit, Param, A_LoopField, `,
Loop, %Param2%
{
If !CountDown
Gosub, CountStop
Send, %Param1%{Enter}
Sleep, %Param3%
}
DelayCount := Param4 / 100
Loop, %DelayCount%
{
If !CountDown
Gosub, CountStop
Sleep, 100
}
}
Gosub, CountStop
CountStop:
Send, {Asc 83}{Asc 116}{Asc 111}{Asc 112}{Enter} ; Send "Stop"
CountDown := False
Exit
---------------->8---------------->8---------------- 请沿此线剪下 ----
如果应用程式不接受 Send {Asc nnnnn} 方式的话，改用剪贴簿复制贴上再试试
--
※ 发信站: 批踢踢实业坊(ptt.cc)
◆ From: 60.248.159.124