作者UndeadSion (UndeadSion)
看板EzHotKey
标题Re: [AHK-] 请教 滑鼠加速
时间Thu Aug 14 23:05:24 2008
※ 引述《RIFF (企业战士)》之铭言：
: 很老的滑鼠，罗技、微软的设定工具都不支援
: 现在「希望滑鼠能加速一倍」
: 1.能直接设定remap吗
: 2.或者需要写一段'抓滑鼠位置->变位'的loop ?
如果滑鼠是用内建驱动程式的话，可以使用呼叫 Windows API 的方法
范例如下
; --------------------------------------------------------------------
; 《滑鼠加速快速键》
;
; Win + F2：关闭滑鼠加速
; Win + F3：滑鼠加速设为一般 (Windows 预设值)
; Win + F4：滑鼠加速设为最高
; --------------------------------------------------------------------
#F2::SetMouseAcceleration(0, 0, 0)
#F3::SetMouseAcceleration(1, 6, 10)
#F4::SetMouseAcceleration(2, 4, 6)
SetMouseAcceleration(MouseSpeed, MouseThreshold1, MouseThreshold2)
{
; SPI_SETMOUSE
VarSetCapacity(MouseAcceleration, 12, 0)
NumPut(MouseThreshold1, MouseAcceleration, 0)
NumPut(MouseThreshold2, MouseAcceleration, 4)
NumPut(MouseSpeed, MouseAcceleration, 8)
DllCall("SystemParametersInfo", UInt, 0x04, UInt, 0, Str, MouseAcceleration, UInt, 0)
; 将设定写入登录
RegWrite, REG_SZ, HKEY_CURRENT_USER, Control Panel\Mouse, MouseThreshold1, %MouseThreshold1%
RegWrite, REG_SZ, HKEY_CURRENT_USER, Control Panel\Mouse, MouseThreshold2, %MouseThreshold2%
RegWrite, REG_SZ, HKEY_CURRENT_USER, Control Panel\Mouse, MouseSpeed, %MouseSpeed%
}
详细说明请参阅 MSDN
http://msdn.microsoft.com/en-us/library/ms724947.aspx
--
※ 发信站: 批踢踢实业坊(ptt.cc)
※ 编辑: UndeadSion 来自: 60.248.159.124 (08/15 11:57)